InnerChild triumphs!!

package
{
	import flash.display.Sprite;
	import flash.net.Responder;
	import flash.net.registerClassAlias;
	import Params;
	public class RemotingTest extends Sprite
	{
		private var rs:RemotingService;
		function RemotingTest()
		{
			init();
		}
		private function init():void
		{
			// amfphp フォルダ内にある、gateway.php の URL を引数に指定。
			rs = new RemotingService("http://sample.innerchild.jp/amfphp/gateway.php");
			// responder を作成。Flash Remoting に成功なら onResult 、失敗なら onFault が呼ばれる。
			var responder:Responder = new Responder(onResult, onFault);
			// Params クラスのエイリアスを "Params" と登録する。
			registerClassAlias("Params", Params);
			var params:Params = new Params();
			params.arg1 = "somthing";
			params.arg2 = int(2);
			// Test.php の メソッド test を 呼びたい時は、第１引数に "Test.test" と指定。
			// 第３引数に php 側に送る、AS のオブジェクトを指定。
			rs.call("Test.test", responder, params);
		}
		private function onResult(result:Object):void
		{
			trace(result);  // [object Params]
		}
		private function onFault(fault:Object):void
		{
			trace(fault);
		}
	}
}

package
{
	import flash.net.NetConnection;
	import flash.net.ObjectEncoding;
	
	public class RemotingService extends NetConnection
	{
		
		function RemotingService(url:String)
		{
			// エンコーディング を AMF3 で。
			objectEncoding = ObjectEncoding.AMF3;
			connect(url);
		}
	}
}

package 
{
	public class Params
	{
		public var arg1:String;
		public var arg2:int;
	}	
}

<?php
class Params
{
	// AS 側で登録したエイリアス "Params" を指定 $_explicitType に指定。
	public $_explicitType = "Params";
	public $arg1;
	public $arg2;
}
?>

<?php
class Test
{
    function test($params)
    {
        //Params オブジェクトをそのまま返す。
        return $params;
        //↓のように書けば、Params オブジェクトの arg1 プロパティにアクセスできます。
        //return $params->arg1;
    }
}
?>